LightCharts是一个轻量级的flex线状图表库。

背景
LightCharts是因为我的一个项目制作的，需要追踪股票市场的众多信息。开始我使用 AdobeFlex的图表库，但是我发现使用 Adobe Flex提供的图表，表现起来很糟糕。随着数据量的增加，需要的时间也要相应的增加。当然，这并不一定是由于Adobe的编码不够优良造成的。他们的库需要包含各种个样的功能来处理不同的需求，所以它们显的很重。我不需要更多的功能，仅仅需要数据的灵活显示。
我搜索网上的第三方图表库，我发现了Keith Peters做的一套漂亮的组件库叫做 Minimal Comps。Keith的库很轻量是一个不错的选择，但是MinimalComps是建立在flash环境下的不是为flex准备的，最主要的问题还是组件的生命周期问题。
他的代码给了我灵感，所以我决定使用它作为我的模型，按照我需要的方式修改。

特点
这个图表组件库有许多新特点和一些新的对象类，包括显示增强和数据交互。例如数据的序列类可以再图形上显示多条线。该工具的架构可以通过创建插件的形式增加数据的处理，而不需要改变任何图表的基类。所以，线状图表类的子类可以有不同的显示方式和特征。我的项目包含了两个图表的例子一个是MACD（指数平滑异同移动平均线）另一个是随机线。
备注：这些例子只是教你如何从基类中扩展你需要的类，而不是教你计算MACS和随机图表的值，至于它们的计算公式可以在网上找到。

演示截图

在演示的截图里你可以看到许多特点：

• 三种不同的图表（标准，MACD和随机）显示不同的背景包括图像，透明度，线条的颜色，和值得范围。
• 在第一个图表上，有一个十字线当鼠标经过的时候会有数字出现，所有的图表都有这样的功能。
• 在第一个和第二个图表上有一个自定义的工具叫DotDisplayTool，它是在数据序列的结尾处显示的小点。DotDisplayTool是一个非交互是插件的例子。
• 在第二个和第三个图表上有一个自定义工具叫做LinearDrawTool，它允许你在数据上根据起始和终止位置绘制直线并显示图表的值。LinearDrawTool是一个交互插件的例子。

示例与源代码

从后面的链接查看示例：LightCharts live demo

源代码遵循MIT license，请从这里下载

• 2010年04月22日 -- 我最想转载的air电子书帖【由airia网整理与提供下载】 (1)

参考文章：http://www.cnblogs.com/holybozo/archive/2010/06/17/1759635.html

LoaderMax是一个新的As3加载系统，它不仅能将swf、mp3、css、video、image、text、binary、xml等文件加载到你的flash应用里，而且加载文件十分简单。它的文件大小惊人，只有其他加载系统的一半，但是却实现了一些特殊的功能。

地址：http://www.greensock.com/loadermax/

这里有一些值得注意的特点：

• 在要加载的swf里面集成加载器
• LoaderMax中自动解析XML
• 为任何加载器定义备用URL
• 为所有的加载器提供统一的属性和方法设置
• 可以为图片加载器、Swf加载器、视频加载器设置宽高，当其加载完，图片、swf、视频可以自动匹配你所设定的宽高
• 一个加载者可以拥有多个LoaderMax实例
• 实时报告加载进度
• 在一行代码里设置多个事件监听：new LoaderMax({name:”mainQueue”, onComplete:completeHandler, onProgress:progressHandler, onError:errorHandler});
• 具有暂停加载及恢复加载的功能
• 对Flex很友好

1、线性化下载过程
一般的下载队列，是一口气推入n个loader，然后逐个下载，下载完了调用start，开始整个程序。

由于是线性过程，这个时候下载流程比较好控制。假如碰到被下载的一个swf中，又下载别的图片、音乐之类，就成了树形过程了。LoaderMax在这方面的处理是利用一个requireWithRoot 属性，指定该Loader隶属于哪个容器。一旦指定，那么这个Loader所下载内容，就当作容器的一部分。

比如 main.swf > (a.swf > a.mp3) > (b.swf > b.jpg)， a.mp3 和 b.jpg都远大于两个swf。

当main在下载的时候，先下a.swf，完了下b.swf。而a.swf中会去下载a.mp3，b.swf则是下载b.jpg。所以很可能出现的情况是a,b.swf都下载好了，还在同时下载a.mp3和b.jpg。但这个时候main已经算下完了，要start了…

如果在a.swf下载a.mp3时设置requireWithRoot = root，b.swf也一样。那么main.swf在a.swf之后下a.mp3，直到a.mp3下载完了，才算a.swf下完。这样就把一个树形流程又改为线性的了。

2、预估文件大小
在下载文件时，都知道有个请求过程，这个过程中文件的总大小是不知道的。这样对显示进度就是个麻烦事儿。像以前碰到公司内网关上安了2b防火墙，进来的数据都隔那儿堵着，等cache满到一定大小才一下子返回。搞得每次在公司看loading都是一闪而过，这不是因为快，是因为前面堵着呢，只能傻等着….LoaderMax在这方面采用了预估文件大小，利用一个estimatedBytes 属性，先假设要下的文件大小是多少。这样一来，即使请求还没来，下载进度还是有的。如果网络不出问题，等到请求返回了，马上就拿精确的文件大小替换预估值，让进度始终保持在用户眼前，而不会傻等。这个属性的默认大小是 20000 (20k)。

3、tween式初始化
这个就不多说了，还是那句话，没用过TweenLite、TweenMax的人还有么？

4、显示对象的对齐
显示对象在下载后有个比较恼人的问题，就是定位和对齐。这个问题其实已经被TransformManager 很好的解决掉了。LoaderMax只是让操作更简单了。

只需在初始对象的属性里面增加width,heighth或scaleX,scaleY（前者优先权大于后者）再配合scaleModes属性就很轻松了。

5、选择性打包
实际上LoaderMax并不是一个万能下载器，他只是一个壳儿，具体的下载交给SWFLoader,XMLLoader,MP3Loader…等等，这样的话，项目中要啥就选啥，可以节约文件大小。编译的时候也不会浪费不必要的时间。

6、并行下载
一般的下载队列，就是逐个下载吧？LoaderMax有个maxConnections 属性，可以设置同时下载数。默认为2。

7、下载信息
还有件比较烦人的事情，就是在定义一个loader后，有时候还要再为之定义个变量，指向下载对象。该指向还必须得在下载好以后才能设置。

这点LoaderMax也封装掉了。LoaderMax.getContent()，而且由于Loader事先就是有类型信息的，像CSSLoader,MP3Loader，所以content在使用上有着很高的可读性。

• 2010年07月31日 -- 在麻球做着快乐而有趣的工作【关注大脸猫的新浪围脖】 (0)
• 2010年05月14日 -- 第3次“中国Flash开发者交流会”火热报名中 (0)
• 2010年08月19日 -- 使用AS3中的FTE与TLF来渲染文本【一】 (0)
• 2010年04月8日 -- 如何给cat-album准备数据【album的数据模型】 (2)
• 2010年08月18日 -- 马鉴：盛大Mochi发布面向中国Flash游戏开发者的游戏平台 (0)
• 2010年08月24日 -- 第5届 FLASH开发者交流会 暨FLASH CAMP 2010 (1)

那么它是如何搭档的呢？我写了这个ThumbRoll类，看看示例吧。

使用方法：

var thumbRoll:ThumbRoll;

//create thumbRoll
var thumbvars:Object={childMargin:10,childPad:8,childWidth:120,childHeight:90,pageNum:4};
thumbRoll=new ThumbRoll(albumData["imgUrlArr"],ThumbDrag,ThumbUI,thumbvars,"x");
thumbRoll.addEventListener("gotoImage",gotoImage);
addChild(thumbRoll);
thumbRoll.dragY=100;
thumbRoll.dragX=0;

function gotoImage(e:Event):void {
	trace(thumbRoll.current);
}

这个类的参数说明：ThumbRoll(_thumbArr:Array,_dragUi:Class,_thumbUi:Class,$vars:Object,$aix:String=”x”)

_thumbArr:Array 所有图片的地址的数组
_dragUi:Class 拖动按钮的绑定类

_thumbUi:Class 缩略图的背景UI绑定类

$vars:Object 这个对象会接收五个参数,可以设置以下属性

pageNum: 每页子对象数
childWidth: 子对象宽
childHeight: 子对象高
childPad: 子对象内边距
childMargin: 子对象外边距

$aix:String 水平或是垂直方向，”x”为水平，”y”为垂直。

dragX 属性 可以设置拖动条的水平位置

dragY 属性 可以设置拖动条的垂直位置

nextPage()方法 翻到下一页

prePage()方法 翻到上一页

hideDrag()方法 如果不需要拖动条，可以用此方法隐藏

pickPosition(n:Number)方法 可以通过点击拖动横条获取鼠标的位置来定位拖动杆

updateThumb(n:Number)方法 可以从外部更新当前缩略图为第几张

autoRollPage()方法 当前缩略图到达新的分页时可以从外部驱动翻页

有兴趣的朋友可以下载原文件看看。

• 2010年05月5日 -- dragRoll拖动翻页类【rollPage的黄金搭档】 (1)
• 2010年02月2日 -- 水平与垂直滚屏类RollPage (2)

在flash中每次都要很麻烦的用getChildAt或getChildByName一层一层的来访问皮肤中的元件，这里设计了一种更简洁的方式来获得设计人员制作的flash文件中的元件或绑定类。
只要继承Skin类并作一些简单的设置就可以用$()方法直接获得某个ui元件,$c()获得某个绑定类,$u获得包含多个ui元件的ui模块。
我通过一个示例文件来详细讲述skin类中的几种用法。

示例文件从这里下载：skin-sample

我们先来看看示例皮肤文件中的类绑定截图


先用皮肤的文档类继承Skin类，skin类继承了Sprite类，所以不用担心文档类需要继承Sprite的问题
皮肤文件端：

package {
	import flash.display.Sprite;
	import com.monboo.skin.Skin;
	public class CatSkin extends Skin {
		public function CatSkin() {
		}
	}
}

再在文档类的构造方法中定义皮肤中提供的对象。

通过三种方法定义皮肤中的对象
public function addClass(cl:Class,cName:String):void
addClass定义绑定类
public function addUI(cName:String,uName:String):void
addUI定义显示对象模块
public function addMap(mapName:String,path:String):void
addMap定义显示对象模块某层级的对象的访问映射

最后在加载皮肤的应用程序端访问皮肤中的对象：

/********
** load skin
*********/
var albumSkin:Object;
var __albumSkin:Class;
var skinUrl:String="http://www.xncat.com/wp-content/uploads/2010/05/catSkin.swf";
loadSkin();

function loadSkin():void {
	var loadSkin:Loader = new Loader();
	var context:LoaderContext = new LoaderContext();
	context.checkPolicyFile=true;
	context.applicationDomain=new ApplicationDomain(ApplicationDomain.currentDomain);
	loadSkin.load(new URLRequest(skinUrl),context);
	loadSkin.contentLoaderInfo.addEventListener(Event.COMPLETE,skinLoadedFunc);
}
function skinLoadedFunc(e:Event):void {
	__albumSkin=e.target.applicationDomain.getDefinition("CatSkin") as Class;
	albumSkin = new __albumSkin();

	trace("[Skin loaded successfully!]");
}

主要有三种访问皮肤内容的方法
1 . 访问皮肤中的类
例如我们要获得皮肤中的CtrlUI,PlayerBoxUI,ThumDrag,ThumbUI几个类，从而实现在皮肤文件加载完成后，可以方便的得到这些类的引用，这种情况适用方法1.
皮肤文件端：
public function addClass(cl:Class,cName:String)
cl:Class参数：在皮肤文件中的绑定类
cName:String参数：加载皮肤后获得这个绑定类的名称

addClass(ThumbUI,"ThumbUI");
addClass(ThumbDrag,"ThumbDrag");
addClass(CtrlUI,"CtrlUI");
addClass(PlayerBoxUI,"PlayerBoxUI");

加载皮肤的应用程序端：
public function $c(cName:String):Class
cName:String参数：加载皮肤后获得这个绑定类的名称

var thumbDrag:Class = albumSkin.$c("ThumbDrag") as Class;
var thumbUI:Class = albumSkin.$c("ThumbUI") as Class;
var ctrlUI:Class = albumSkin.$c("CtrlUI") as Class;
var playerBoxUI:Class = albumSkin.$c("PlayerBoxUI") as Class;

2 . 访问皮肤中的显示对象模块
比如我们要访问皮肤文件中一个实例化的显示模块volumeControl，它里面有比较复杂的显示对象层级，有比较多的按钮对象，我把为了方便把这个模块绑定成一个类，在应用程序端只需要获得这个模块实例，并addChild到显示列表中就行了。
皮肤文件端：
public function addUI(cName:String,uName:String):void
cName:String参数：加载皮肤后获得这个模块绑定类的名称
uName:String参数：在皮肤文件中模块的实例名

addClass(VolumeControl,"VolumeControl");
addUI("VolumeControl","vControl");

加载皮肤的应用程序端：
public function $u(uName:String):Sprite{
uName:String参数：在皮肤文件中模块的实例名

addChild(albumSkin.$c("vControl"));

3 . 访问皮肤中的 显示对象模块中的某一个ui
当我们获得了某个显示对象模块后，如何访问它里面比较复杂的显示对象层级，就可以用到这第三种方法了。
皮肤文件端：
public function addMap(mapName:String,path:String):void
mapName:String参数：映射名，通过这个名称可以获得某一个层级的显示对象
path:String参数：映射路径，如vControl.volumUp.soundLine

addClass(VolumeControl,"VolumeControl");
addUI("VolumeControl","vControl");
addMap("soundLine","vControl.volumUp.soundLine");

加载皮肤的应用程序端：
public function $(mapName:String):Sprite
mapName:String参数：映射名，通过这个名称可以获得某一个层级的显示对象

var soundLine:Sprite = albumSkin.$("soundLine"));

注：

你可以把皮肤ui分离成一个独立的皮肤文件用于应用程序加载，也可以不分离把皮肤ui跟应用程序位于同一文件。如果是分离的话，你得在加载成功后的方法中获取皮肤中的对象，如果不分离的话，可以直接访问皮肤中的对象。

• 2010年08月29日 -- flash开发中提高性能方法的整理 (1)
• 2010年08月18日 -- 小s：盛大游戏麻球网上线 Flash独立游戏开发者的曙光 (0)
• 2010年08月18日 -- 腾讯博客：Flash Mini Game 盈利平台出现 (0)
• 2010年08月18日 -- 谈熠：做自己心仪的游戏发布给1亿个人 (1)
• 2010年08月18日 -- 猫粮：独立游戏开发者春天 (0)
• 2010年08月18日 -- 马鉴：盛大Mochi发布面向中国Flash游戏开发者的游戏平台 (0)

再看看示例demo：



DragRoll跟RollPage的参数很相似，不愧是搭档。
DragRoll(target:Sprite,rollMc:Sprite,$vars:Object)

target:Sprite  : 拖杆对象
rollMc:Sprite ：需要被拖动的对象，把所有内容都放在这个容器中，如多个图片或者各分页内容
$vars:Object ：这个对象会接收五个参数,可以设置以下属性

pageNum:每页子对象数
totalNum:总子对象数
childWidth:子对象宽
childHeight:子对象高
childMargin:子对象边距

使用这个类的方法：
DragRoll类使用注意：
//所有的图片都在rollMc中，
//rollMc在别的容器中，必须保证rollMc的x,y坐标都为0

var dragObj:Object={pageNum:4,totalNum:14,childWidth:150,childHeight:125,childMargin:10};

//rollMc一定要在别的容器中，保证它的x,y坐标都为0
var dragBar:DragRoll=new DragRoll(bar,container.rollMc,dragObj);
addChild(dragBar);
dragBar.x=35;
dragBar.y=150;

//可以在barLine上点击定位拖杆到想要的位置
barLine.addEventListener(MouseEvent.CLICK,pickPosition);
barLine.buttonMode = true;
function pickPosition(e:MouseEvent):void {
dragBar.pickThumbBar(barLine.mouseX);
}

dragRoll示例与源代码下载

补充说明：
目前此类还不支持垂直拖放；
拖杆还不能动态改变长度。

• 2010年06月22日 -- 看看dragRoll与rollPage是如何搭档【ThumbRoll类】 (0)
• 2010年02月2日 -- 水平与垂直滚屏类RollPage (2)
• 2010年04月25日 -- 滚屏翻页类新版本rollPage2 (3)
• 2010年02月7日 -- 制作滚屏与翻页时分页加载的方法 (0)

我也收集了些意见对rollPage类作了一些重要修改，使它更完善了。

新版本的rollPage主要有以下变化

1. 增加setRoll方法来接收参数，不再是构造函数中传递参数了 实现了可以通过一个rollPage对象可以动态的修改翻页属性并切换不同pageMc进行翻页控制，这个功能应用的例子：

2.  翻到最后一页时，如果子对象数不足一整页，会只翻过最后这一页有的子对象数，不再是翻滚一整页 有无这个功能应用的例子对比：

3. 修改rollMask高或宽多出一个childMargin尺寸问题

再展示一些应用示例截图

让大家形象的了解rollPage类可以用来做什么：用来翻滚flash中的显示对象作翻页效果

来看看setRoll方法有哪些参数：

setRoll($pageMc:Sprite,$vars:Object,$aix:String=”x”)

$pageMc:Sprite ：把所有内容都放在这个容器中，如多个图片或者各分页内容
$vars:Object ：这个对象会接收五个参数,可以设置以下属性

pageNum:每页子对象数
totalNum:总子对象数
childWidth:子对象宽
childHeight:子对象高
childMargin:子对象边距

$aix:String ：设置为垂直还是水平翻滚

使用这个类的方法：

rollPage类使用注意：
//所有的图片都在vImageMc中，
//vImageMc在别的容器中，必须保证vImageMc的x,y坐标都为0

var pageRoll:RollPage=new RollPage(); pageRoll.setRoll(vImageMc,{total:12,pageNum:5,childWidth:100,childHeight:75,childMargin:15});

//左右按钮
left.buttonMode=right.buttonMode=true;

left.addEventListener(MouseEvent.CLICK,function (e:MouseEvent):void{pageRoll.toRoll(pageRoll.page-1);}); right.addEventListener(MouseEvent.CLICK,function (e:MouseEvent):void{pageRoll.toRoll(pageRoll.page+1);});

rollPage2.0示例与源代码下载

• 2010年05月5日 -- dragRoll拖动翻页类【rollPage的黄金搭档】 (1)
• 2010年02月7日 -- 制作滚屏与翻页时分页加载的方法 (0)
• 2010年02月2日 -- 水平与垂直滚屏类RollPage (2)

查看文档可以看到，从InteractiveObject这个抽象基类开始有这个属性。

所以DisplayObjectContainer, SimpleButton, TextField 这些显示对象都可以你都可以设置它们的 contextMenu属性，来隐藏你不需要的默认菜单项，和添加自定义的菜单项。

var my_menu:ContextMenu = new ContextMenu();
my_menu.hideBuiltInItems();
DisplayObjectContainer.contextMenu = my_menu;

这是最简单隐藏所有默认菜单项的方法（“设置” 与 “关于”两项除外 ）。

如果你不想一次隐藏所有项，也可以一项项设置哪些项隐藏。

var my_menu:ContextMenu = new ContextMenu();
my_menu.builtInItems.forwardAndBack = false;
my_menu.builtInItems.loop = false;
my_menu.builtInItems.play = false;
my_menu.builtInItems.print = false;
my_menu.builtInItems.quality = false;
my_menu.builtInItems.rewind = false;
my_menu.builtInItems.save = false;
my_menu.builtInItems.zoom = false;
DisplayObjectContainer.contextMenu = my_menu;

那么可不可以完全隐藏所有菜单项呢？目前我还没有找到这样的方法，只看到这样一段话：

If you test your movie now you should see that your default zoom and playback settings are gone from your context menu. You should note that certain items such as Settings and About cannot be removed from the context menu. Some additional commands for debugging cannot also be removed either while testing in the Flash authoring tool.

添加自己的菜单项，就用下面的方法：

var my_menu:ContextMenu = new ContextMenu();
my_menu.hideBuiltInItems();

var my_blog:ContextMenuItem= new ContextMenuItem("猫脸爬格子");
var my_email:ContextMenuItem = new ContextMenuItem("rman@live.cn");
var my_copyright:ContextMenuItem = new ContextMenuItem("Copyright - 2009");
my_menu.customItems.push(my_blog,my_email,my_copyright);

DisplayObjectContainer.contextMenu = my_menu;

每一个ContextMenuItem对象除了菜单文字外，还有两个属性比较有用。

enabled : Boolean 指示指定的菜单项处于启用状态还是禁用状态（能否点击）。

separatorBefore : Boolean 指示指定的菜单项上方是否显示分隔条。

my_copyright.enabled = false;
my_copyright.separatorBefore = true;

为ContextMenuItem对象添加menuItemSelect 事件：ContextMenuEvent.MENU_ITEM_SELECT

var url:String;
my_blog.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, openLink);
my_email.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, openLink);
function openLink(e:ContextMenuEvent):void{
    switch(e.currentTarget.caption){
        case 猫脸爬格子:
        url = "www.xncat.com";
        break;
        case rman@live.cn:
        url = "www.xncat.com/email";
        break;
    }
    navigateToURL(new URLRequest(url));
}

有网友写了个ContextMenuPlus类，可以很方便的处理以上各菜单定制功能。

• 2010年06月25日 -- Flash Builder Profiler——修复ExternalInterface上的内存泄露 (0)
• 2010年08月18日 -- Y.boy：最大的在线游戏网络，flash游戏产业的颠覆者：麻球网 (1)
• 2009年12月6日 -- actionscript与javascript交互 (3)
• 2010年01月29日 -- cat风格的loading文件技术分析 (2)
• 2010年01月5日 -- 学习向量的心得[fxzjw的文章] (0)
• 2010年05月20日 -- Adobe展示流畅运行Flash的Android平板电脑【转载】 (2)

此类只需要把图片对象作为参数传入，就可以实现对图片的移动编辑操作，因为默认的编辑状态就是移动状态。

var t:TransformPic = new TransformPic(picmc);
addChild(t);

另外还可以分别依次传入参数：移动，旋转，缩放状态切换按钮。

var t:TransformPic = new TransformPic(picmc,movebt,scalebt,rotatebt);
addChild(t);

在开发这个类的时候，有两个难点：
1. 缩放的中心点，如何改变图片的注册点到我们指定的坐标点；
2. 旋转的中心点，修改注册点同上。

网上有很多方案，但都不是很完美，会引各种不便，而yahoo的as类库中有一个修改对象注册点的类：DynamicRegistration.as
这个类很简单，我们需要用到里面的两个方法：

//旋转需要传入要修改到的坐标点，与旋转的角度数
DynamicRegistration.rotate(picMc,p,ro);
//缩放需要传入要修改到的坐标点，与x轴的缩放比，与y轴的缩放比
DynamicRegistration.scale(picMc,p,1+sc*0.01,1+sc*0.01);

下面是完整的类与示例原文件下载：

package {
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import flash.events.Event;
	import flash.text.TextField;
	import flash.geom.Point;
	import com.yahoo.astra.utils.DynamicRegistration;

	/**
	 * @author robin@tudou / email:xnliao@tudou.com
	 * @version creat:
	 */
	public class TransformPic extends Sprite {
		private var picMc:Sprite;
		private var moveBt:Sprite;
		private var scaleBt:Sprite;
		private var rotateBt:Sprite;

		private var transPlane:Sprite;
		private var transBtMc:Sprite;

		private var oldy:Number;
		private var nowx:Number;
		private var vy:Number=0;
		private var sc:int=0;
		private var ro:int=0;
		private var p:Point;

		public function TransformPic($picMc:Sprite,$moveBt:Sprite = null,$scaleBt:Sprite = null,$rotateBt:Sprite = null) {
			//用于编辑的图片，与此图片的中心点
			picMc=$picMc;
			p = new Point(picMc.width/2,picMc.height/2);

			//用于侦测鼠标操作编辑动作的按钮
			transPlane=makeArea(picMc.width,picMc.height,0.2);
			addChild(transPlane);
			transPlane.x = picMc.x;
			transPlane.y = picMc.y;

			//切换编辑状态的按钮
			transBtMc = new Sprite();
			addChild(transBtMc);
			if($moveBt){moveBt=$moveBt;transBtMc.addChild(moveBt);}
			if($scaleBt){scaleBt=$scaleBt;transBtMc.addChild(scaleBt);}
			if($rotateBt){rotateBt=$rotateBt;transBtMc.addChild(rotateBt);}

			addEvent();
			tomove(null);
		}

		private function addEvent():void {
			if(moveBt){this.moveBt.addEventListener(MouseEvent.CLICK, tomove);}
			if(scaleBt){this.scaleBt.addEventListener(MouseEvent.CLICK, toscale);}
			if(rotateBt){this.rotateBt.addEventListener(MouseEvent.CLICK, torotate);}
			transPlane.addEventListener(MouseEvent.MOUSE_OUT, transout);
		}
		private function transout(e:MouseEvent):void {
			picMc.stopDrag();
			transPlane.removeEventListener(MouseEvent.MOUSE_MOVE, scalehd);
			transPlane.removeEventListener(MouseEvent.MOUSE_MOVE, rotatehd);
		}
		private function tomove(e:MouseEvent):void {
			transformType("move");
		}
		private function toscale(e:MouseEvent):void {
			transformType("scale");
		}
		private function torotate(e:MouseEvent):void {
			transformType("rotate");
		}

		//move
		private function toDrag(e:Event):void {
			picMc.startDrag();
		}
		private function toStopDrag(e:Event):void {
			picMc.stopDrag();
		}

		//scale
		private function scaleon(e:MouseEvent):void {
			transPlane.addEventListener(MouseEvent.MOUSE_MOVE, scalehd);
			oldy=mouseY;
		}
		private function scaleoff(e:MouseEvent):void {
			transPlane.removeEventListener(MouseEvent.MOUSE_MOVE, scalehd);
		}
		private function scalehd(e:MouseEvent):void {
			e.updateAfterEvent();
			vy=transPlane.mouseY-oldy;
			oldy=transPlane.mouseY;

			if (vy>0) {
				if (sc < -90) {
					sc = -91;
				} else {
					sc--;
				}
			}
			if (vy<0) {
 				if (sc>200) {
					sc=201;
				} else {
					sc++;
				}
			}
			DynamicRegistration.scale(picMc,p,1+sc*0.01,1+sc*0.01);
		}

		//rotate
		private function rotateon(e:MouseEvent):void {
			transPlane.addEventListener(MouseEvent.MOUSE_MOVE, rotatehd);
			oldy=mouseY;
		}
		private function rotateoff(e:MouseEvent):void {
			transPlane.removeEventListener(MouseEvent.MOUSE_MOVE, rotatehd);
		}
		private function rotatehd(e:MouseEvent):void {
			e.updateAfterEvent();
			vy=transPlane.mouseY-oldy;
			oldy=transPlane.mouseY;
			nowx=transPlane.mouseX;

			if (nowx<transPlane.width/2){
                                 if (vy>0) {
					if (ro < -180) {
					ro = -181;
					} else {
					ro--;
					}
				}
				if (vy<0) {
 					if (ro>180) {
						ro=181;
					} else {
						ro++;
					}
				}
			} else {
				if (vy<0) {
					if (ro < -180) {
 					ro = -181;
 					} else {
 					ro--;
 					}
				}
 				if (vy>0) {
					if (ro>180) {
						ro=181;
					} else {
						ro++;
					}
				}
			}
			DynamicRegistration.rotate(picMc,p,ro);
		}

		/**************************************
		** makeArea
		** 一些辅助方法
		***************************************/
		public function makeArea(w:uint,h:uint,alpha:Number= 0.5):Sprite {

			var area:Sprite=new Sprite  ;
			area.alpha=alpha;
			area.graphics.beginFill(0x000000,1);
			area.graphics.drawRect(0,0,w,h);
			area.graphics.endFill();
			return area;

		}
		private function transformType(type:String):void{
			transPlane.removeEventListener(MouseEvent.MOUSE_DOWN, toDrag);
			transPlane.removeEventListener(MouseEvent.MOUSE_UP, toStopDrag);
			transPlane.removeEventListener(MouseEvent.MOUSE_DOWN, scaleon);
			transPlane.removeEventListener(MouseEvent.MOUSE_UP, scaleoff);
			transPlane.removeEventListener(MouseEvent.MOUSE_DOWN, rotateon);
			transPlane.removeEventListener(MouseEvent.MOUSE_UP, rotateoff);

			if(type == "move"){
				transPlane.addEventListener(MouseEvent.MOUSE_DOWN, toDrag);
				transPlane.addEventListener(MouseEvent.MOUSE_UP, toStopDrag);
			}else if(type == "scale"){
				transPlane.addEventListener(MouseEvent.MOUSE_DOWN, scaleon);
				transPlane.addEventListener(MouseEvent.MOUSE_UP, scaleoff);
			}else if(type == "rotate"){
				transPlane.addEventListener(MouseEvent.MOUSE_DOWN, rotateon);
				transPlane.addEventListener(MouseEvent.MOUSE_UP, rotateoff);
			}
		}

	}
}

示例原文件下载

• 2010年02月28日 -- 无锯齿缩放图片【缩放时对位图进行平滑处理】 (1)

这个类很好用，它可以完成多个内容的分页，滚屏与翻页功能。垂直或水平翻滚都可以，而且会自动计算是否到达第一页或者最后一页。
看看这个例子，我经常用到这个类。

先来看看它有哪些参数：
RollPage($pageMc:Sprite,$vars:Object,$aix:String=”x”)
$pageMc:Sprite ：把所有内容都放在这个容器中，如多个图片或者各分页内容
$vars:Object ：这个对象会接收五个参数

$vars["totalNum"]：总内容个数，比如总共多少张图片
$vars["pageNum"]：设定每而或每屏显示多少个内容，比如每页显示几张图片
$vars["childPad"]：设置每个内容之间的间隔距离
$vars["childWidth"]：设置每个内容的高度
$vars["childHeight"]：设置每个内容的宽度

$aix:String ：设置为垂直还是水平翻滚

使用这个类的方法：

rollPage类使用注意：
//所有的图片都在vImageMc中，
//vImageMc在别的容器中，必须保证vImageMc的x,y坐标都为0

var pageRoll:RollPage=new RollPage(vImageMc,{totalNum:12,pageNum:5,childWidth:100,childHeight:75,childPad:15});

//左右按钮
left.buttonMode=right.buttonMode=true;
left.addEventListener(MouseEvent.CLICK, function (e:MouseEvent):void{pageRoll.toRoll(pageRoll.page-1);});
right.addEventListener(MouseEvent.CLICK, function (e:MouseEvent):void{pageRoll.toRoll(pageRoll.page+1);});

每页中的内容如何排列，可以看看《加载图片(读取xml,json数据)并进行阵列》

实例文件下载:rollPage.rar

完整的类文件：

package {
	import flash.display.Sprite;
	import com.gs.TweenLite;

	/**
	 * @author robin
	 */
	public class RollPage {
		private var pageMc:Sprite;
		private var vars:Object;
		private var aix:String;
		private var pageNum:uint=1;

		private var childNum:uint;
		private var pageChild:uint;
		private var spanLength:uint;
		private var childWidth:uint;
		private var childHeight:uint;
		private var childPad:uint;

		public function RollPage($pageMc:Sprite,$vars:Object,$aix:String="x") {
			pageMc=$pageMc;
			vars=$vars;
			aix=$aix;

			childNum=$vars["totalNum"];
			pageChild=$vars["pageNum"];
			childPad=$vars["childPad"];

			childWidth=$vars["childWidth"];
			childHeight=$vars["childHeight"];

			var mask:Sprite;
			if ($aix=="x") {
				spanLength = (childWidth+childPad)*pageChild;
				mask=makeArea(spanLength,childHeight);
			} else if ($aix == "y") {
				spanLength = (childHeight+childPad)*pageChild;
				mask=makeArea(childWidth,spanLength);
			}

			var pageParent:Sprite=pageMc.parent as Sprite;

			pageParent.addChild(mask);
			mask.x=pageMc.x;
			mask.y=pageMc.y;
			pageMc.mask=mask;
		}

		public function toRoll($pageNum:uint):void {

			if ($pageNum<=0) { 				trace("firepage"); 			} else if ($pageNum > Math.ceil(childNum/pageChild)) {
				trace("endpage");
			} else {
				if (aix=="x") {
					TweenLite.to(pageMc,.5,{x:-($pageNum-1)*spanLength});
				} else if (aix == "y") {
					TweenLite.to(pageMc,.5,{y:-($pageNum-1)*spanLength});
				}
				pageNum=$pageNum;
			}

		}

		public function set page(num:uint):void {
			this.pageNum=num;
		}
		public function get page():uint {
			return this.pageNum;
		}
		private function makeArea(w:uint,h:uint,alpha:Number= 0.5):Sprite {
			var area:Sprite=new Sprite  ;
			area.alpha=alpha;
			area.graphics.beginFill(0x000000,1);
			area.graphics.drawRect(0,0,w,h);
			area.graphics.endFill();
			return area;
		}
	}
}

• 2010年05月5日 -- dragRoll拖动翻页类【rollPage的黄金搭档】 (1)
• 2010年02月7日 -- 制作滚屏与翻页时分页加载的方法 (0)
• 2010年06月22日 -- 看看dragRoll与rollPage是如何搭档【ThumbRoll类】 (0)
• 2010年04月25日 -- 滚屏翻页类新版本rollPage2 (3)

var num:unit = getObjNum(12.35,100);
private function getObjNum(aNum:Number,total:Number):uint{
	var objNum:uint;

	var denfen:uint = 4;
	var bi:Number = aNum/total;

	if(bi >= 0.75){
        	objNum = 3;
	}else if(bi >= 0.45 && bi < 0.75){
        	objNum = 2;
	}else if(bi >= 0.25 && bi < 0.45){
        	objNum = 1;
	}else if(bi >= 0 && bi < 0.25){
        	objNum = 0;
	}
	return objNum;
}

很快就把算法写出来了，那如果把题目改一下
问：如果把100以内的数分成n份，取任意一个100以内的数，如何知道这个数是第几份中的？

var n:uint = 8;
var num:unit = getObjNum(12.35,100);
private function getObjNum(aNum:Number,total:Number):uint{
	var objNum:uint;

	var denfen:uint = n;
	var bi:Number = aNum/total;

	for(var i:uint=0;i<denfen;i++){
		if(bi >= i/denfen && bi < (i+1)/denfen){
			objNum = i;
			break;
		}
	}

	return objNum;
}	

还可以再改进吗？也许做这个判断并不需要跑for循环吧。而且我运行程序后，发现有一些小bug，拖到最右边时，有时候返回错误的位置编号。
改进版

var n:uint = 8;
var num:uint = getObjNum(12.35,100);
private function getObjNum(aNum:Number,total:Number):uint{
        var objNum:uint = Math.min(n-1, Math.floor(aNum / total* n));
        return objNum;
}

ok，把上面的问题搞明白了，接下来就好办了。制作这个拖放与置换的示例，需要实现如下两个关键点：
1. 获取指定位置编号上的按钮对象；
2. 获取指定按钮对象所在的位置编号（其实就是根据按钮对象的坐标值，算出它是n个等份中的第几份）。

使用DragFollow类很简单。只需要把两个参数传给它就可以了：var theDrag:DragFollow = new DragFollow(btAllMc,600);
一个是包含了所有拖放按钮的容器对象，
一个是X轴上可以拖放的范围（Y轴可以吗？当然可以，我在类文件中写了个_aix的参数，默认值为空，
把Y轴相关的开发留给大家去思考了！）

先添加鼠标拖与放的事件，以及具体的拖放事件函数，这些都放在构造函数中。

public function DragFollow(_parentMc:Sprite,_trackLength:Number,_aix:String=null){
	//所有拖放按钮的容器对象
        parentMc = _parentMc;
	//轴上可以拖放的范围
        trackLength = _trackLength;

	for(var i:uint=0;i<parentMc.numChildren;i++){
		var ch:Sprite = parentMc.getChildAt(i) as Sprite;
		ch.buttonMode = true;
		ch.mouseChildren = false;
		ch.addEventListener(MouseEvent.MOUSE_DOWN,this.starDragFunc);
		ch.stage.addEventListener(MouseEvent.MOUSE_UP,this.endDragFunc);
	}

}
private function starDragFunc(e:MouseEvent):void{
	targetMc = e.target as Sprite;
	dragState = true;

	//记录当前拖动对象
	moveObj.targetObj = targetMc;
	moveObj.targetPosition = targetMc.x;

	var rectangle:Rectangle = new Rectangle(0, 0, trackLength, 0);

	//设置当前拖动对象显示层级到最上层，并把拖动限制在一个轴
	parentMc.setChildIndex(targetMc,parentMc.numChildren-1);
	targetMc.startDrag(false,rectangle);
}
private function endDragFunc(e:MouseEvent):void{
	if(dragState){
		targetMc.stopDrag();
		dragState = false;

		//设置目标位置编号
		//根据拖动对象停止的坐标，设置将要停放到几号位置
		setNum(targetMc.x,trackLength);
		setChildPostion();
	}
}

设置目标位置编号，根据拖动对象停止的坐标，设置将要停放到几号位置，然后与目标停放位置上的对象交换位置。

private function setNum(position:Number,total:Number):void{
	num = Math.min(denfen-1, Math.floor(targetMc.x / trackLength * denfen));
}
private function setChildPostion():void{
	//目标停放位置上的对象
	moveObj.toChangeBt = getNumObj(num);
	moveObj.toChangePosition = moveObj.toChangeBt.x;

	//与目标停放位置上的对象交换位置
	TweenLite.to(targetMc,0.2,{x:moveObj.toChangePosition});
	TweenLite.to(moveObj.toChangeBt,0.2,{x:moveObj.targetPosition});
}

嗯，还有这个类文件中最关键的两个方法，那就是获取目标位置编号上的对象，与获取目标对象的位置编号。

//获取目标位置编号上的对象
public function getNumObj(_num:uint):Sprite{
	var ch:Sprite;
	for(var i:uint=0;i<parentMc.numChildren;i++){
		var bt:Sprite = parentMc.getChildAt(i) as Sprite;
		if(getObjNum(bt.x,trackLength) == _num){
			ch = bt;
			break;
		}
	}
	return ch;
}

//获取目标对象的位置编号
private function getObjNum(position:Number,total:Number):uint{
	var denfen:uint = parentMc.numChildren;
	var objNum:uint = Math.min(denfen-1, Math.floor(position / total * denfen));

	return objNum;
}	

That is it! 有了这个类，在项目中处理这种拖放置换功能就好办多了，如果需要把Y轴也开发进来，大家自己动手吧。
完全的项目文件可以到这里下载

• 2009年11月23日 -- 国产动画“功夫兔”系列：《菜包狗大反击》 (0)
• 2010年01月3日 -- 20个最佳的flash游戏教程[转载] (2)
• 2010年08月18日 -- 谈熠：做自己心仪的游戏发布给1亿个人 (1)
• 2010年07月31日 -- 首届“麻球Flash开发者大赛”重奖开启 (1)
• 2009年12月3日 -- 叫兽：魔术记 (0)
• 2009年12月18日 -- 大脸猫露脸 (0)

private function updateColor():void {
	var cm:ColorMatrix = new ColorMatrix();
	cm.adjustHue(rotateNum);
	light.filters = [new ColorMatrixFilter(cm)];// 需要变换色相的light，是一个mc
	liveColor_bg.filters = [new ColorMatrixFilter(cm)];//需要变换色相的liveColor_bg，是一个mc
}

当然使用它的adjustColor方法，就可以分别改变图片的明度，对比度，纯度，色相。
adjustColor(p_brightness:Number,p_contrast:Number,p_saturation:Number,p_hue:Number)
brightness：明度，
contrast：对比度，
saturation：纯度，
hue：色相

2) RollMc，则是我的小作啦，它是一个很简单的类，只用来通过鼠标产生旋转，和得到旋转数值rotateNum。
使用方法：RollMc(_overBt:Sprite,_rollMc:Sprite)，只需要传递两个参数给它。
一个是产生mouseOver的按钮，一个是需要被旋转的对象，这两个参数都必须是Sprite类型的。比如这个示例中，需要在全舞台进行旋转，就可以做一个全舞台大小的透明按钮，来捕捉mouseOver即可。

我们来看看如何通过产生旋转与旋转数值，以及变换颜色的原理来创造有趣的动画效果吧。

• 2009年12月6日 -- 百威啤酒-击打鼓点游戏 (0)
• 2010年02月9日 -- 猫猫拳打可怜小狗！ (0)
• 2009年11月22日 -- wp-swfobject为博客嵌入flash (3)
• 2010年04月20日 -- Flash字体嵌入方法总结—(3)ActionScript提高篇【转载kevincao】 (0)
• 2009年12月2日 -- Paint.NET 3.5速度如系统自带画图工具，功能齐全 (1)
• 2010年01月5日 -- 学习向量的心得[fxzjw的文章] (0)

当用户快速频繁的点击错误的区域时，它就会抛出警告，

并且扣掉我们大把游戏时间。

ClickCheck是一个单例，使用起来很方便。

ClickCheck.toCheck(_target);
//target是需要检测的区域，通常是一个mc
//只要在这个mc上点击，就会进行检测是否有频繁点击

还可以自定义最大点击数与点击间隔时间

ClickCheck.toCheck(_target,_totalNum,_timeOff);
//totalNum是当用户频繁点击多少次后就触发事件
//timeOff是判断多长时间间隔内再次点击视为频繁点击

完全的ClickCheck代码：

package{
        import flash.display.Sprite;
        import flash.events.MouseEvent;
        import flash.utils.getTimer;

        /**
        * @author robin
        */
        public class ClickCheck {
                private var oldClickTime:Number = 0;
                private var clickNum:uint = 0;
                private var totalNum:uint;
                private var timeOff:Number;

                private static var instance:ClickCheck;

                public function ClickCheck(){}

                public static function toCheck(_target:Sprite,_totalNum:uint=3,_timeOff:Number=0.4):void{
                        if(instance==null){
                                instance = new ClickCheck();
                        }
                        instance.totalNum = _totalNum;
                        instance.timeOff = _timeOff;
                        _target.addEventListener(MouseEvent.CLICK, instance.cClick);
                }
                private function cClick(evt:MouseEvent):void{
                        var clickTime:Number = getTimer()*0.001;

                        if(oldClickTime!= 0 && (clickTime - oldClickTime) <= instance.timeOff){
                                trace("[one fast click]");
                                if(clickNum < instance.totalNum){
                                        clickNum++;
                                }
                                if(clickNum == instance.totalNum){
                                        trace("[----no more fast click]");

                                        clickNum = 0;
                                }
                        }else{
                                clickNum = 0;
                        }

                        oldClickTime = clickTime;

                }
        }
}

接下来我要留一个问题供大家思考，如果需要检测多个目标区域呢，比如有多个mc需要检测，并且用户可能一会在这个mc上点几下，一会又在另一些mc上点几下。
我就不写了，把空间留给大家。

• 2010年07月26日 -- 在麻球发布游戏作品的详细教程（转aspirin） (0)
• 2009年12月3日 -- 保存图片到服务器类(php服务器) (10)
• 2010年08月18日 -- 腾讯博客：Flash Mini Game 盈利平台出现 (0)
• 2010年01月24日 -- 中国flash开发者交流会上演讲完成了 (6)
• 2010年02月28日 -- as3四种方法实现文本居中 (0)
• 2009年11月17日 -- wp-al-swfobject为博客自定义嵌入flash (0)

摄像头拍照或视频截图类：http://www.xncat.com/2009/12/catflash/334.html

图片上传类[UpLoadPic]：http://www.xncat.com/2009/12/catflash/340.html

保存图片到服务器类(php服务器)：http://www.xncat.com/2009/12/catflash/368.html

————————————

我们知道flash中将本地图片上传到服务器使用的是FileReference对象，那么如何将flash中的显示对象，如movieClip,Sprite,Video等截图并保存到服务器上呢？这个保存图片到服务器类SaveDrawPic.as就是为此而设计的。
演示demo

要实现这个功能需要用到JPGEncoder 类，相关说明网上很多。

来看一下怎么使用这个SaveDrawPic类，至少需要传递三个参数给它。
SaveDrawPic(_drawMc:Sprite,_saveBt:Sprite,_txt:TextField,_w:Number=320,_h:Number=280)
_drawMc：你需要截取哪一个显示对象的图像，
_saveBt：一个保存按钮，用来触发向服务器保存图片的动作，
_txt：友好提示文本。

关于拍照功能前面《摄像头拍照或视频截图类》已经讲过了，本例增加了把拍照的图片显示到右边的展示区的功能（最多展示四张）。
使用了addToThumb，removeSaveContentChild，resetSaveContent几个方法，可以下载原文件看看它们的具体实现。

var getV:GetVideoImage = new GetVideoImage(v,recam_bt,cam_bt,txt);
getV.addEventListener("completeCamPic",completeCamPicFunc);
function completeCamPicFunc(e:Event):void{
	camPicContent.addChild(getV.getPrecamPic());
	addToThumb(getV.getPrecamPic());
}

SaveDrawPic类使用方法：
以拍照图片的容器camPicContent为绘制对象，在舞台创建保存按钮，利用原来拍照中的提示文本，依次作为参数传给SaveDrawPic的实例。并侦听此实例发出的“saveSuccess”事件，此事件会在右边的文本区域输出图片地址。
通过SaveDrawPic类的getpicUrl方法可以获得图片在服务器上的地址。

var saveV:SaveDrawPic = new SaveDrawPic(camPicContent,save_bt,txt);
saveV.addEventListener("saveSuccess",saveSuccessFunc);
function saveSuccessFunc(e:Event):void{
	txtArea.text = saveV.getpicUrl();
}

此类中也有isenabled方法，这是一个可以很方便给Sprite,MovieClip,SimpleButton等显示对象添加或移除鼠标事件的方法。
在另一篇文章《摄像头拍照或视频截图类》中有详细的说明。
示例原文件下载

• 2009年12月1日 -- 图片上传类[UpLoadPic] (4)
• 2009年12月1日 -- 摄像头拍照或视频截图类 (8)
• 2010年07月26日 -- 开发与上传麻球游戏教程（n神版） (1)

摄像头拍照或视频截图类：http://www.xncat.com/2009/12/catflash/334.html

图片上传类[UpLoadPic]：http://www.xncat.com/2009/12/catflash/340.html

保存图片到服务器类(php服务器)：http://www.xncat.com/2009/12/catflash/368.html

————————————

不用说，做各种flash游戏或者互动应用的时候，让用户上传图片，或者自定义头像都会用到图片上传功能。为了能够灵活复用，我写了这个UpLoadPic类。

上传图片需要服务器端的支持，使用这个类的话，请给类中的upLoadAPI属性填写你的服务端接口地址，如 http://xxx.tudou.com/global/tool/upload_pic.php?fileType=.jpg 在这个类中。

为了预览上传的图片，我用到了ImageLoader类，这个类比较方便对加载的图片创建多个实例。

演示demo :

使用方法：

创建浏览按钮，上传按钮，友好提示文本，并依次把它们作为参数传递给UpLoadPic类即可。
通过UpLoadPic类的getPreviewPic()方法可以获得上传后的预览图片对象，它是一个Sprite类型对象。
也可以通过getPicUrl()方法获得上传后的图片地址。

var upLoadPic:UpLoadPic = new UpLoadPic(br_bt,up_bt,txt);
previewContent.addChild(upLoadPic.getPreviewPic());

这个类主要使用FileReference对象来实例选择本地图片与上传到服务器。

file=new FileReference();
file.addEventListener(Event.SELECT,selectHandler);
file.addEventListener(Event.CANCEL,cancelHandler);
file.addEventListener(IOErrorEvent.IO_ERROR,ioErrorHandler);
file.addEventListener(ProgressEvent.PROGRESS,progressHandler);
file.addEventListener(Event.COMPLETE,completeHandler);
file.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,dataHandler);

注意浏览的方法中加入对图片类型的限制，如
var fileFilter:FileFilter=new FileFilter(“文件类型”,”*.jpg;*,png;*.gif”);
file.browse([fileFilter]);

上传的方法中则需要加入对图片大小的限制与提示。

var fileSize:uint=file.size;
if (fileSize>1024*300) {
        this.uploadText.text="文件太大！请上传小于300k的图片";
}
//浏览
private function browseFunc(evt:MouseEvent):void {
        var fileFilter:FileFilter=new FileFilter("文件类型","*.jpg;*,png;*.gif");
        file.browse([fileFilter]);
}
//上传
private function uploadFunc(evt:MouseEvent):void {
        var fileSize:uint=file.size;
        if (fileSize>1024*300) {
                this.uploadText.text="文件太大！请上传小于300k的图片";
        } else {
                var url:String=upLoadAPI;
                var uploadURL:URLRequest=new URLRequest(url);
                uploadURL.method=URLRequestMethod.POST;
                file.upload(uploadURL);
        }
}

此类中也有isenabled方法，这是一个可以很方便给Sprite,MovieClip,SimpleButton等显示对象添加或移除鼠标事件的方法。
在另一篇文章《摄像头拍照或视频截图类》中有详细的说明。
示例原文件下载

• 2009年12月3日 -- 保存图片到服务器类(php服务器) (10)
• 2009年12月1日 -- 摄像头拍照或视频截图类 (8)
• 2010年07月26日 -- 开发与上传麻球游戏教程（n神版） (1)

摄像头拍照或视频截图类：http://www.xncat.com/2009/12/catflash/334.html

图片上传类[UpLoadPic]：http://www.xncat.com/2009/12/catflash/340.html

保存图片到服务器类(php服务器)：http://www.xncat.com/2009/12/catflash/368.html

————————————

开发flash项目时，经常会遇到需要用摄像头拍照，或者对视频进行截图。所以我写了这个类GetVideoImage
无论是摄像头还是视频，都是用Video对象来负责播放视频流，
所以拍照或视频截图都是对video用BitmapData.draw方法来截图视频的图像。
演示demo :

使用方法：

创建一个Video对象，重拍按钮，拍照按钮，友好提示文本，然后依次把它们作为参数传递给GetVideoImage类的实例。并侦听此实例发出的”completeCamPic”事件。”。
通过GetVideoImage类的getPrecamPic方法可以获得拍照或截取所得的图片对象，它是一个Sprite类型。

var v:Video = new Video(320,280);
videoContent.addChild(v);
var getV:GetVideoImage = new GetVideoImage(v,recam_bt,cam_bt,txt);
getV.addEventListener("completeCamPic",completeCamPicFunc);
function completeCamPicFunc(e:Event):void{
	camPicContent.addChild(getV.getPrecamPic());
}

在这里介绍一下GetVideoImage类中的isenabled方法，这个方法可以给Sprite,MovieClip,SimpleButton等显示对象添加或移除鼠标点击事件。
需要给它传递三个参数：isenabled(btMc:DisplayObject,isable:Boolean,fn:Function)
btMc为需要添加事件的显示对象
isable为true添加事件，为false移除事件
fn为事件绑定的函数

function isenabled(btMc:DisplayObject,isable:Boolean,fn:Function):void {
        var bt;
        if (isable) {
                if(btMc is Sprite){bt = btMc as Sprite;bt.buttonMode=true;}else{bt = btMc;}
                bt.addEventListener(MouseEvent.CLICK,fn);
                bt.alpha=1;
        } else {
                if(btMc is Sprite){bt = btMc as Sprite;bt.buttonMode=false;}else{bt = btMc;}
                bt.removeEventListener(MouseEvent.CLICK,fn);
                bt.alpha=0.5;
        }
}

添加事件后，鼠标经过按钮对象会变成手形，点击触发绑定的函数，
移除事件后，鼠标经过按钮没有手形，点击无事件，按钮变成半透明效果。

示例原文件下载

• 2009年12月3日 -- 保存图片到服务器类(php服务器) (10)
• 2009年12月1日 -- 图片上传类[UpLoadPic] (4)
• 2010年07月26日 -- 开发与上传麻球游戏教程（n神版） (1)